Coming in with a lot of (continuous numerical) data, I struggled to find a neat chart type to display it. I went for a contour plot but it needs the data sorted in rows and columns while my data consisted of 5000 rows and two columns. Manual ordering would have been possible but to work intensive (5000 rows!). And since COUNTIF does not come with the ability two compare two criteria (or I just did not find it) I figured out a pretty good workaround. By the way, this works in Excel2007 but should work in 2003 and 2010 too.

Let’s assume I have got the data for a process (like a flow and a temperature) and I would like to see where the main operating point of a piece of equipment is. This requires three dimensions and is best shown in a countour plot (fig. a).

Fig. a) The contour plot

The data structure we need can be seen here. In the case of TL;DR we need columns for x values (or x value categories in the case of continuous numerical data) and rows for the y values (or categories). What I needed was the number of value pairs (x and y) fitting into each of the category pairs. But before that:

Setting up the data grid

An example spreadsheed follows at the end of this article, feel free to peek into it to follow my explanations.
Since we want to sort values (value pairs) we need some categories they fit in. To set up a category grid I first retrieved the following variables:

The value ranges can be retrieved by the functions MIN and MAX. To have even values as categories, it is proven useful to nest those intoFLOOR respectively CEILING. Caveat: FLOOR and CEILING in excel do round AWAY from zero and need a significance related to the actual value.
So, if you’d like to FLOOR all values (away from zero) and you’ve got positive and negative numbers you could write =FLOOR(yourCell,IF(yourCell>=0, 1,-1)).
If you’d rather like to have a floor rounding like in ActionsScript you would need to write =IF(yourCell<0, CEILING(yourCell, -1), FLOOR(yourCell,1)) or the other way around for the 'real' ceiling rounding.

I recommend the second if you need categories in the negative to get the best bounds. The significance also has potential to influence the display of the data, so choose that depending on what you got or looks best.

The span just is the difference between min and max range value. I will not post the formula for this one. If you can't figure that out, you probably should not use excel or look it up in the attached example spreadsheet.

The step size is the quotient of span by grid size.

Categorization

Now that we have that, we set up three more columns:

The x and y category column hold the quotients of the actual value by step size. Using FLOOR returns the value by means of greater than or equal to the lower bound and less than the upper bound.

The core piece of this workaround is the category column. With =CONCATENATE(x category cell, "-", y category cell) a hybrid label is created, in that case it returns something like "1-3" or "4-2" which is exactly one of the combinations we later look for with COUNTIF. If your gird size is equal to or exceeds 10 you may need to add leading zeros by =CONCATENATE(IF(I3<10, "0", ""), I3, "-", IF(J3<10, "0", ""), J3). The returned values the look like "01-10" or "04-04". But that is more of an aesthetical thing.

The grid data and the chart

Now that's pretty simple again. Set up a table with x categories as the column headers and y categories as row headers. Enter =COUNTIF(category column, CONCATENATE(IF(x catgory<10,"0",""),x category,"-",IF(y category<10,"0",""),y category)). What it does is computing the category name (the combination) on the fly and counting how many labels in the category column it equals.

The surface.xlsx spreadsheet

Then just mark the cells (insert some row and column headings to use in the chart if you like first) and insert a surface chart or contour plot.

surface plot

Something I tested also, was a 3D column chart as a 3D histogram.

histogram

It might sound difficult at first but feel free to play with the example and make some nice charts. If there are questions just post a comment.
Source: SurfaceData.xlsx

Circular text can be useful in several designs, so here is a little class that produces the following:

What the swf shows is first the ‘debug-version’ which changes after a click to the naked text version. Consecutive clicks will produce the same for randomized values.

CircleText.as

package
{
	import flash.display.Sprite;
	import flash.geom.Matrix;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;

	/**
	 * CircleText.as
	 * @author kegogrog
	 */
	public class CircleText extends Sprite
	{
		private static const degToRad:Number = Math.PI / 180;

These are the basic imports and the private var degToRad used for the conversion of degrees into radians.

		public function CircleText( startAngle:Number = -90, endAngle:Number = 90, radius:Number = 80, inner:Boolean = false, text:String = "This text is a test.", debug:Boolean = true )

The class accepts several inputs, the most important are startAngle, endAngle and radius. I hope I do not need to explain those. inner defines if the text is located on the outside of the circle or on the inside. text should be pretty obvious and debug just defines what one can see. I recommend to delete that once the class is implemented while it is nothing the user has to see.

		{
			var tff:TextFormat = new TextFormat();
			tff.font = "calibri";
			tff.size = 20;

It is important to use an embedded font, so here I am just defining a text format. One could also reference that in the constructor or use a global format.

			var sr:Number = startAngle * degToRad;
			var er:Number = endAngle * degToRad;

			if ( debug )
			{
				this.graphics.lineStyle(0, 0xcccccc);
				this.graphics.drawCircle(0, 0, 3);
				this.graphics.drawCircle(0, 0, radius);
				this.graphics.drawCircle(Math.sin(sr) * radius, -Math.cos(sr) * radius, 4);
				this.graphics.drawCircle(Math.sin(er) * radius, -Math.cos(er) * radius, 2);
			}

The angles are converted to radians and if debug is true the midpoint, the circle itself are drawn and the start and end of the text is marked.

			var i:int;
			var tf:TextField;
			var m:Matrix;
			for ( i = 0; i < text.length; i++ )
			{
				tf = new TextField();
				tf.selectable = false;
				tf.autoSize = TextFieldAutoSize.LEFT;
				tf.defaultTextFormat = tff;
				tf.embedFonts = true;
				tf.text = text.charAt(i);

				if ( debug )
				{
					tf.background = true;
					tf.backgroundColor = 0xcccccc;
					tf.alpha = 0.8;
				}

				m = new Matrix();
				m.translate( -tf.width * 0.5, -tf.height * ( inner ? 0 : 1 ) - radius );
				m.rotate( sr + ( ( er - sr ) / ( text.length - 1 ) ) * i );
				tf.transform.matrix = m;

				addChild(tf);
			}
		}
	}
}

The biggest code chunk here splits the string into single characters, creates a textfield for each one and applies translation (depending on inner) and rotation according to the start and end angle and the characters position in the string. The translation in x moves the textfield so that it is centered.

I was using FlashDevelop for this presentation with the following

Main.as

:

package
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.text.TextField;

	/**
	 * Main.as for CircleText
	 * @author kegogrog
	 */
	public class Main extends Sprite
	{
		[Embed(
			source = 'font/calibri.ttf',
			fontName = "calibri",
			fontWeight = "normal",
			advancedAntiAliasing = "true",
			mimeType = "application/x-font",
			fontStyle = "normal",
			embedAsCFF = 'false',
			unicodeRange = 'U+0020-U+007E'
			)]
		private var calibri:Class;

		private var startAngle:Number = -90;
		private var endAngle:Number = 90;
		private var radius:Number = 80;
		private var inner:Boolean = false;
		private var text:String = "This text is a test.";
		private var debug:Boolean = true;

		private var ct:CircleText;

		public function Main():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point

			buildText();
			stage.addEventListener(MouseEvent.CLICK, buildText);
		}

		private function buildText(event:MouseEvent = null):void
		{
			if ( ct )
			{
				removeChild(ct);
			}
			ct = new CircleText( startAngle, endAngle, radius, inner, text, debug );
			ct.x = stage.stageWidth >> 1;
			ct.y = stage.stageHeight >> 1;
			addChild(ct);

			if ( !debug )
			{
				startAngle = Math.random() * 360;
				endAngle = startAngle + Math.random() * 180 + 90;
				radius = Math.random() * 30 + 50;
				inner ? inner = false : inner = true;
			}
			debug ? debug = false : debug = true;
		}
	}
}

buildText takes the predefined variables and adds a new CircleText. With the next click it shows the non-debug version and and changes the variables prior to the next click.

Being a sprite, CircleText can be rotated by its own rotation property. One could also put all text fields into an array and animate them, maybe flying of the screen from the center. Have fun playing with that.

Yoho!

Yay, new game! What, another match three? Come on, that’s going to get boring. But wait, there is something different in there.
Alright, here is my new game. Years ago, I had this on a phone and really liked it but never found anything like it in flash. So, I made it. Again with FlashDevelop and without any single graphical asset. Seems I developed an interest in computer generated graphics. With all the given filters in flash it’s pretty simple though to make something shiny.

Ok, some facts and pictures. The first fact: I forgot why I choose blue as the main theme.

The menu screen with kegMenu™, German & muted

Programming the game took approximately 2 days. Doing the framework was the harder part. Or shall I say overdoing. That’s what I tend to. All communication between classes is now done with custom events. And wow, these are powerful. I used a state machine for the first time and that makes sense when creating a game without lag.

The game itself comes, like TriPop, with a timed mode, where one has several seconds to score as many points as possible, and my favourite skilled mode, where only moves cost energy and no clock stresses the player. The new thing here is the hexagonal positioning of the balls and that you need to turn triplets either clockwise or counterclockwise to form lines (basic match three game description goes here…) of three or more balls of the same color. With chains longer than three balls or more than one chain on the initial turn you can regain energy. So, choose wisely and play forever. Balancing was big part here, since the timed mode in TriPop allowed the player to swap gems at no cost and thus create really long chains and score high, higher, woot. This time, turning the triplet comes with energy cost (evil grin here).

I first wanted to include a simple pattern mode (different colored balls displaying different patterns) for a better differentiation between the different balls that could be usable for e.g. colorblind people. It turned out, that I made the patterns, which were simple dots at first, a little bit more entertaining.

The game with pattern mode turned off (above) and on

The game comes in 10 languages. English and German were done by me, the rest was done by a part of the great Mochi Community, namely:

• Ernesto Quezada, Spanish
• LustiGames, Hungarian
• Maras, Czech
• kcnh, Dutch
• kou, Greek
• Pavel, Russian
• J.K.S., Finnish
• José Ferreira, Portuguese

So, in the attempt to let people help you on a specific task, the most important thing I learned is: BE SPECIFIC ABOUT WHAT YOU WANT. I did send out the strings I needed to be translated and installed a test version of the game. What I should have done in addition would have been some descriptions for my dearest translation team to really know that I mean, because aside from SPO there may be other differences in languages… Well, that was one learning. It went pretty good though for a first try. Use short sentences and don’t focus on reusability of single words. The second important was, you may need a fallback font for special characters. Or, upfront, choose a font that supports those. There is a file size optimization possibility I did use for the first languages. It is ‘only embed the needed fonts’. But you can run into trouble there. So be careful. Write a little program, feed it all your strings, let it sort out the uniques and embed those. Otherwise you may miss one or two.

So, aside from all that I included some progression. With every game played, the points are summed and with every level gained the player gets more energy for the next game. Let’s see if I can make it to level 99 (it’s unlimited by the way).

The game over screen showing the players progress

The player’s level is also accessible from the kegMenu™ and there is another leaderboard for the level reached. So, if you are interested you can track my addiction to this game.

Since it’s above 30 degrees Celsius now I’m running out of all the cool stuff I wanted to write. Oh, nearly forgot, here is a link to the game.

Yoho, the game (you just lost it). I love memebase.

What’s necessary for putting a flash game on facebook? Not much. I did that by putting a php file onto my server which acts as the canvas file. Into the same folder I unpacked the FB PHP SDK. FB likes developers and thus gives you an application profile page, the only thing you have to worry about is the actual canvas page.

To create an app for TriPop I followed the normal procedure, added an app in the developer section, copied the given keys, created the php file, filled out several, mostly self explaining, fields including the path to my file and there it is. TriPop’s application profile page and the TriPop application itself.

The FB SDK, once unpacked needs to go onto the server to as the php will refer to it.

The code for a simple application canvas (no approval by the user required because no user data is used) looks like this:

<?php
// Awesome Facebook Application
//
// Name: Application Name
//

require_once 'facebook-php-sdk/src/facebook.php';

// Create our Application instance.
$facebook = new Facebook(array(
  'appId' => '***************',
  'secret' => '********************************',
  'cookie' => false,
)); 

?>

<div style = " text-align: right; width: 640px; margin-bottom: 5px; ">
	Back to
	<fb:application-name
		linked="true"
	/>
	's application page
</div>

<div style = " text-align: center; width: 640px; margin-bottom: 5px; ">
	<fb:swf
		swfbgcolor="ffffff"
		swfsrc='http://www.yarrcade.com/gamefiles/tripop/TriPop.swf'
		width='640' height='480'
	/>
</div>

The first div is just for a text field at the top that can be used as a back button to the application profile page. The next div encloses the swf. And that is all. Really…

For more information refer to the FB Developer Documentation. Just if you need to go deeper or if you want to use more functions. Moreover, for dedicated development on the FB platform you may want to have a look at Michael’s new book.

Embedding asstes into your FD project is pretty simple. In fact it is as easy as 1, 2, 3. One: Copy, two: embed, three: use. Let’s go!

1. Copy

Alright, with your assets ready you should create a folder in your project folder or even in src. For the following example I created the folder sounds for (obviuosly) sounds and copied the font directly into src.

The FD project folder

2. Embed

Embedding a font efficiently means knowing which glyphs you need. The following is a great source for finding Unicode ranges.

	public dynamic class Main extends MovieClip
	{
		[Embed(
			source = 'BERLIN.TTF',
			fontName = "berlinSans",
			fontWeight = "bold",
			advancedAntiAliasing = "true",
			mimeType = "application/x-font",
			fontStyle = "normal",
			embedAsCFF = 'false',
			unicodeRange = 'U+0020,
					U+0041-U+005A,
					U+0061-U+007A,
					U+0030-U+0039,
					U+002E, U+002F,
					U+0027, U+00A9,
					U+00E4, U+00FC'
			)]
		private var berlinSans:Class;

		[Embed( source = 'sounds/SoundPop.mp3')]
		private var SoundPop:Class;
		public var soundPop:Sound;

		[Embed(source = 'sounds/sound12.mp3')]
		private var SoundSwap:Class;
		public var soundSwap:Sound;

		[Embed(source = 'sounds/WintersDream.mp3')]
		private var Music:Class;
		public var music:Sound;

All embeds are followed directly by private vars, defining the embedded assets as classes. To use them public vars are created. Caveat: If you create folders anywhere, remember the path ( for source)!

3. Use

		public function Main():void
		{
			music = new Music();
			soundPop = new SoundPop();
			soundSwap = new SoundSwap();

The fonts are used simply by referring to the fontName you set in the embed section. By setting yourTextField.embedFonts you can use your font.

			iFormat = new TextFormat();
			iFormat.font = "berlinSans";
			iFormat.color = 0xaaaaaa;
			iFormat.size = 24;

			gameName = new TextField();
			gameName.embedFonts = true;
			gameName.defaultTextFormat = iFormat;
			gameName.text = "yourText here";
			addChild(gameName);
			gameName.selectable = false;
			gameName.autoSize = TextFieldAutoSize.LEFT;

Pretty much always you should set yourTextField.selectable to false. As a player I am always a bit picky when it comes to buttons where the text selection tool shows up.

The same thing goes with graphics I think though I didn’t try that.

Yoho!

The selfish creation. I like match three games, so I made one. What I don’t like in games is time pressure whatever more ‘excitement’ it may bring. So I made me a little relaxing game. When I thought about making it public I added a timed mode, because there are people who like that. The most interesting fact from the developer side of view: I did the whole game in FlashDevelop and there is not a single graphical asset included. It’s all code generated.

Strategic alignment:

• Create a casual game as expandable and thus exploitable template
• Learn to work with FlashDevelop

The mechanism of a match three is trickier than thought. I decided against a flood fill check algorithm and instead used a double loop (rows, then columns). That way the first check is cheaper because only the swapped region (1 row and 2 cloumns or 2 rows and 1 column) is checked. I managed to implement detection of all kinds of combos. By checking rows first and columns later there are combinations that aren’t easily marked as having the same elements. But a little backwards loop over all found matches afterwards did that.

The game features:

• A title screen with the expanded kegMenu^® and some fluffy clouds floating around. The game uses automatic language detection via System.Capabilities for english and german.


The TriPop menu screen

• A settings screen with full sound control (main, music and effects) as well a language choice.


The TriPop settings screen

• A screen showing the basic instructions


The TriPop help screen

• A screen that informs the player that a link he clicked is not working. This is mostly due to the parameters allowNetworking or allowScriptAccess set by the site owner. When it is detected via try...catch the link is copied to the clipboard and the user is informed that he can just paste it into the address bar. I didn’t want to block the game at this moment. One could include the domain where the links are blocked for a dynamic blacklist or something but blocking the game would be rather annoying for the player.


The TriPop link block alert

• And a little ‘console screen’ though no input is possible. I included it just for me to see if the game is working correctly. It is accessible via keyboard input ‘IDDQD’. In-game this leads to a faster game end, a feature that I needed to test the leaderboards.


The TriPop developer console

• And of course the game. As this is the developer log I just wanted to show off the gimmicks first. As already mentioned, all graphics are code generated. The size of the final swf including the MochiAds preloader is 307KB with:
  • 238KB for the background loop (‘Winter’s Dream’, also on NewGrounds Audio)
  • 10KB for the sound effects
  • 39KB for the game itself


A TriPop game screenshot

And here is the game link.

Have fun playing it and leave a comment if you like to. Though it is still no ‘industrial standard’, I feel that this is my most professional work and I had a lot of fun developing it with only free tools. FlashDevelop is very comfortable for writing code, not only regarding the space on the screen for conding on a laptop monitor.

Yoho!

A little further experiment with 3D makes me want to play LHX or D-Track.

If the movie does not react to keyboard input, click once inside of it to give it focus.

There are a lot of optimization opportunities, though the frame rate seems to be pretty stable. Smoothing the terrain could be next, depth sorting is obviuosly not the best. Well, that’s what weekends are for, right?

Source? Sure: ZIP (13.9 KB)

Please tell me in the comments if it works for you and if you experience any lags.

Yoho!

Click the movie to give focus to the keyboard.

With the code derived from the last post I wanted to try to get multiple (partly moving) objects into an environment that moves. Done. There are two “racers” on a plane. One of the racers is moving while the “camera” is panning around the plane.

Interested in the source? It would definitely look better if it wasn’t timeline code.

var world:MovieClip = new MovieClip();
world.x = stage.stageWidth*0.5;
world.y = stage.stageHeight*0.5;
addChild( world );

var focalLength:Number = 500;

var allPointsArray:Array = new Array();
var centerPointsArray:Array = new Array();

var triangleArray:Array = new Array();

var plane = new Object();
plane.center = make3DCenter( 0, 0, 0, plane );
plane.rot = make3DCenter( 0, 0, 0, plane );
plane.pointsArray = [
					make3DPoint(-200,-200,0, plane),
					make3DPoint(-200,200,0, plane),
					make3DPoint(200,200,0, plane),
					make3DPoint(200,-200,0, plane),
					];

plane.triangles = [
				   makeTriangle(plane.pointsArray[0], plane.pointsArray[1], plane.pointsArray[2], 0x000000),
				   makeTriangle(plane.pointsArray[0], plane.pointsArray[2], plane.pointsArray[3], 0xdddddd)
				   ];

var object1 = new Object();
object1.center = make3DCenter( 0, 100, 0, object1 );
object1.rot = make3DCenter( 0, 0, 0, object1 );
object1.pointsArray = [
					   make3DPoint( 30,  0,  0, object1),
					   make3DPoint(-30,  0,  -20, object1),
					   make3DPoint(-30,-20,  0, object1),
					   make3DPoint(-30, 20,  0, object1)

];
object1.triangles = [
					 makeTriangle( object1.pointsArray[0], object1.pointsArray[2], object1.pointsArray[1], 0xff0000),
					 makeTriangle( object1.pointsArray[0], object1.pointsArray[1], object1.pointsArray[3], 0x0000ff),
					 makeTriangle( object1.pointsArray[1], object1.pointsArray[2], object1.pointsArray[3], 0x00ff00)
					 ];
object1.vx = 5;
object1.vy = 5;

var object2 = new Object();
object2.center = make3DCenter( 100, 100, 0, object2 );
object2.rot = make3DCenter( 0, 0, 0, object2 );
object2.pointsArray = [
					   make3DPoint( 30,  0,  0, object2),
					   make3DPoint(-30,  0,  -20, object2),
					   make3DPoint(-30,-20,  0, object2),
					   make3DPoint(-30, 20,  0, object2)

];
object2.triangles = [
					 makeTriangle( object2.pointsArray[0], object2.pointsArray[2], object2.pointsArray[1], 0xff0000),
					 makeTriangle( object2.pointsArray[0], object2.pointsArray[1], object2.pointsArray[3], 0x0000ff),
					 makeTriangle( object2.pointsArray[1], object2.pointsArray[2], object2.pointsArray[3], 0x00ff00)
					 ];
object2.vx = 0;
object2.vy = 0;

function makeTriangle( p1, p2, p3, col)
{
	var triangle = new Object();
	triangle.points = [p1, p2, p3];
	triangle.col = col;
	triangleArray.push( triangle );
}

function make3DCenter ( x, y, z, o)
{
	var point = new Object();
	point.x = x;
	point.y = y;
	point.z = z;
	point.o = o;
	centerPointsArray.push(point);
	return point;
};

function make3DPoint ( x, y, z, o)
{
	var point = new Object();
	point.ox = x;
	point.x = x;
	point.oy = y;
	point.y = y;
	point.oz = z;
	point.z = z;
	point.o = o;
	allPointsArray.push(point);
	return point;
};

function make2DPoint (x,y, depth, scaleFactor)
{
	var point = new Object();
	point.x = x;
	point.y = y;
	point.depth = depth;
	point.scaleFactor = scaleFactor;
	return point;
};

function get3DPoints ( object )
{
	var sx = Math.sin(object.rot.x);
	var cx = Math.cos(object.rot.x);
	var sy = Math.sin(object.rot.y);
	var cy = Math.cos(object.rot.y);
	var sz = Math.sin(object.rot.z);
	var cz = Math.cos(object.rot.z);
	var x,y,z, xy,xz, yx,yz, zx,zy;
	var i = object.pointsArray.length;
	while (i--){
		x = object.pointsArray[i].ox;
		y = object.pointsArray[i].oy;
		z = object.pointsArray[i].oz;

		xy = cx*y - sx*z;
		xz = sx*y + cx*z;
		yz = cy*xz - sy*x;
		yx = sy*xz + cy*x;
		zx = cz*yx - sz*xy;
		zy = sz*yx + cz*xy;

		object.pointsArray[i].x = zx + object.center.x;
		object.pointsArray[i].y = zy + object.center.y;
		object.pointsArray[i].z = yz + object.center.z;
	}
}

function Transform3DPointsTo2DPoints ( points, axisRotations )
{
	var TransformedPointsArray = [];
	var sx = Math.sin(axisRotations.x);
	var cx = Math.cos(axisRotations.x);
	var sy = Math.sin(axisRotations.y);
	var cy = Math.cos(axisRotations.y);
	var sz = Math.sin(axisRotations.z);
	var cz = Math.cos(axisRotations.z);
	var x,y,z, xy,xz, yx,yz, zx,zy, scaleFactor;

	var i = points.length;
	while (i--){

		x = points[i].x;
		y = points[i].y;
		z = points[i].z;

		xy = cx*y - sx*z;
		xz = sx*y + cx*z;
		yz = cy*xz - sy*x;
		yx = sy*xz + cy*x;
		zx = cz*yx - sz*xy;
		zy = sz*yx + cz*xy;

		scaleFactor = focalLength/(focalLength + yz);

		x = zx*scaleFactor;
		y = zy*scaleFactor;
		z = yz;

		TransformedPointsArray[i] = make2DPoint(x, y, -z, scaleFactor);
	}
	return TransformedPointsArray;
};

var ballArray:Array = new Array();

for ( var i:int = 0; i < allPointsArray.length; i++){
	var ball:MovieClip = new MovieClip();
	var colors = [ 0xffffff, 0x990000 ];
	var fillType:String = GradientType.RADIAL;
	var alphas:Array = [1, 1];
	var ratios:Array = [0x00, 0xff];
	var matr:Matrix = new Matrix();
	matr.createGradientBox(-20*0.4, -20*0.4, 0, 0, 0);
	var spreadMethod:String = SpreadMethod.PAD;
	var interpolationMethod:String = InterpolationMethod.RGB;
	var focal:Number = -0.1;
	with(ball.graphics)
	{
		lineStyle( 1, 0x330000 );
		beginGradientFill( fillType, colors, alphas, ratios, matr, spreadMethod, interpolationMethod, focal );
		drawCircle(0,0,3);
		endFill();
	}
	world.addChild(ball);
	ballArray.push(ball);
}

var cubeAxisRotations = make3DCenter(0,0,0, world);

this.addEventListener( Event.ENTER_FRAME, enterFrameHandler);
function enterFrameHandler( event:Event )
{
	cubeAxisRotations.z += 0.5*Math.PI/180;
	cubeAxisRotations.y = - Math.sin( -cubeAxisRotations.z );
	cubeAxisRotations.x = - Math.cos( -cubeAxisRotations.z );

	object1.center.newX = object1.center.x + object1.vx;
	object1.center.newY = object1.center.y + object1.vy;

	var rz = Math.atan2(object1.vy, object1.vx);
	object1.rot.z = rz;

	if ( object1.center.newX < 200 && object1.center.newX > -200 )
	{
		object1.center.x = object1.center.newX;
	}
	else
	{
		object1.vx*=-1;
	}
	if ( object1.center.newY < 200 && object1.center.newY > -200 )
	{
		object1.center.y = object1.center.newY;
	}
	else
	{
		object1.vy*=-1;
	}

	get3DPoints(plane);

	get3DPoints(object1);
	get3DPoints(object2);

	var screenPoints = Transform3DPointsTo2DPoints(allPointsArray, cubeAxisRotations);
	screenPoints.sortOn("depth");
	for (i=0; i < screenPoints.length; i++)
	{
		var currBall = ballArray[i];
		currBall.x = screenPoints[i].x;
		currBall.y = screenPoints[i].y;
		currBall.scaleX = currBall.scaleY = screenPoints[i].scaleFactor;
		world.addChild(currBall);
	}
	world.graphics.clear();
	world.graphics.lineStyle(0,0x000000);
	for each ( var tri in triangleArray )
	{
		screenPoints = Transform3DPointsTo2DPoints(tri.points, cubeAxisRotations);

		if (
			( screenPoints[2].x - screenPoints[0].x ) * ( screenPoints[1].y - screenPoints[2].y ) >
			( screenPoints[2].y - screenPoints[0].y ) * ( screenPoints[1].x - screenPoints[2].x )
			)
		{
			with(world.graphics)
			{
				beginFill(tri.col, 0.75);
				moveTo(screenPoints[0].x, screenPoints[0].y);
				lineTo(screenPoints[1].x, screenPoints[1].y);
				lineTo(screenPoints[2].x, screenPoints[2].y);
				lineTo(screenPoints[0].x, screenPoints[0].y);
				endFill();
			}
		}
	}
}

Now, with a little sterring behaviour and terrain this could be really nice. Looking at the (to be released) Molehill API and the triangle methods in CS4 it may be not worth the effort, but it still is interesting.

Yoho!

Good Morning!

It took a while to write that. Why the rum? Long story as a link: I saw that and liked it. Copy, paste, trace out all compile fails and rewrite and present!

The (re-coded) code:

var theScene:MovieClip = new MovieClip();
theScene.x = stage.stageWidth*0.5;
theScene.y = stage.stageHeight*0.5;
addChild( theScene );

var focalLength:Number = 300;

function make3DPoint ( x, y, z)
{
	var point = new Object();
	point.x = x;
	point.y = y;
	point.z = z;
	return point;
};

function make2DPoint (x,y, depth, scaleFactor)
{
	var point = new Object();
	point.x = x;
	point.y = y;
	point.depth = depth;
	point.scaleFactor = scaleFactor;
	return point;
};

function Transform3DPointsTo2DPoints (points, axisRotations)
{
	var TransformedPointsArray = [];
	var sx = Math.sin(axisRotations.x);
	var cx = Math.cos(axisRotations.x);
	var sy = Math.sin(axisRotations.y);
	var cy = Math.cos(axisRotations.y);
	var sz = Math.sin(axisRotations.z);
	var cz = Math.cos(axisRotations.z);
	var x,y,z, xy,xz, yx,yz, zx,zy, scaleFactor;

	var i = points.length;
	while (i--){
		x = points[i].x;
		y = points[i].y;
		z = points[i].z;

		// rotation around x
		xy = cx*y - sx*z;
		xz = sx*y + cx*z;
		// rotation around y
		yz = cy*xz - sy*x;
		yx = sy*xz + cy*x;
		// rotation around z
		zx = cz*yx - sz*xy;
		zy = sz*yx + cz*xy;

		scaleFactor = focalLength/(focalLength + yz);
		x = zx*scaleFactor;
		y = zy*scaleFactor;
		z = yz;

		TransformedPointsArray[i] = make2DPoint(x, y, -z, scaleFactor);
	}
	return TransformedPointsArray;
};

var pointsArray:Array = [
	make3DPoint(-50,-50,-50),
	make3DPoint(50,-50,-50),
	make3DPoint(50,-50,50),
	make3DPoint(-50,-50,50),
	make3DPoint(-50,50,-50),
	make3DPoint(50,50,-50),
	make3DPoint(50,50,50),
	make3DPoint(-50,50,50)
];

var ballArray:Array = new Array();

for ( var i:int = 0; i < pointsArray.length; i++){
	var ball:MovieClip = new MovieClip();
	var colors = [ 0xffffff, 0x990000 ];
	var fillType:String = GradientType.RADIAL;
	var alphas:Array = [1, 1];
	var ratios:Array = [0x00, 0xff];
	var matr:Matrix = new Matrix();
	matr.createGradientBox(-40*0.4, -40*0.4, 0, 0, 0);
	var spreadMethod:String = SpreadMethod.PAD;
	var interpolationMethod:String = InterpolationMethod.RGB;
	var focal:Number = -0.1;
	with(ball.graphics)
	{
		beginGradientFill( fillType, colors, alphas, ratios, matr, spreadMethod, interpolationMethod, focal );
		drawCircle(0,0,20);
		endFill();
	}
	theScene.addChild(ball);
	ballArray.push(ball);
}

var cubeAxisRotations = make3DPoint(0,0,0);

theScene.addEventListener( Event.ENTER_FRAME, enterFrameHandler );

function enterFrameHandler( event:Event )
{
	cubeAxisRotations.y -= 5*Math.PI/180;
	cubeAxisRotations.x += 5*Math.PI/180;
	var screenPoints = Transform3DPointsTo2DPoints(pointsArray, cubeAxisRotations);
	for (i=0; i < pointsArray.length; i++){
		var currBall = ballArray[i];
		currBall.x = screenPoints[i].x;
		currBall.y = screenPoints[i].y;
		currBall.xscale = currBall.yscale = 100 * screenPoints[i].scaleRatio;
		//currBall.swapDepths(screenPoints[i].depth);
	}
}

Just don't ask. Yo... -ho!

EDIT: The spam comments, I forgot them. I don't like them. Like: I DON'T LIKE THEM!

EDIT_2: And: Creating the thumbnail was time consuming. More than writing...

EDIT_3: I forgot to include the depths.

function enterFrameHandler( event:Event )
{
	cubeAxisRotations.y -= 2*Math.PI/180;
	cubeAxisRotations.x += 2*Math.PI/180;
	var screenPoints = Transform3DPointsTo2DPoints(pointsArray, cubeAxisRotations);
	screenPoints.sortOn("depth");
	for (i=0; i < screenPoints.length; i++){
		var currBall = ballArray[i];
		currBall.x = screenPoints[i].x;
		currBall.y = screenPoints[i].y;
		currBall.xscale = currBall.yscale = 100 * screenPoints[i].scaleRatio;
		theScene.addChild(currBall);
	}
}